next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
GradedLieAlgebras :: Symmetries

Symmetries -- Operating by permutations of the generators

The function holonomyLie constructs the holonomy Lie algebra of an arrangement or matroid given by the set of 2-flats. The input may be any set of subsets of a finite set, such that all subsets have at most one element in common and are of length at least three. Indeed, for any such set of subsets there is a unique simple matroid of rank at most three with the given set as the set of 2-flats of size at least three, and holonomyLie gives the holonomy Lie algebra of this matroid.

i1 : L = holonomyLie({{1,2,3},{1,4,5},{2,4,6}})

o1 = L

o1 : LieAlgebra
i2 : L.relsLie

o2 = {{{1, 1, 1}, {[2, 1], [2, 2], [2, 3]}}, {{1, 1, 1}, {[3, 1], [3, 2], [3,
     ------------------------------------------------------------------------
     3]}}, {{1, 1, 1}, {[4, 1], [4, 4], [4, 5]}}, {{1, 1, 1}, {[5, 1], [5,
     ------------------------------------------------------------------------
     4], [5, 5]}}, {{1, 1, 1}, {[4, 2], [4, 4], [4, 6]}}, {{1, 1, 1}, {[6,
     ------------------------------------------------------------------------
     2], [6, 4], [6, 6]}}, [3, 4], [2, 5], [3, 5], [1, 6], [3, 6], [5, 6]}

o2 : List
i3 : decompidealLie 3

o3 = {}

o3 : List

The kernel of the map from L to the direct sum of the local Lie algebras, see localLie, is decompidealLie. Since it is the empty set, L is the direct sum of the local Lie algebras. They may be obtained using localLie (observe that the numbering of the flats begins with 0).

i4 : localLie(2,4)

o4 = {[4, 4, 6, 4], [6, 4, 6, 4], [6, 6, 6, 4]}

o4 : List

The kernel of the map from L to one of the local Lie algebras, in degree at least two, may be obtained as follows (i0 is the kernel of the map from L to the first local Lie algebra, etc).

i5 : i0=idealBasisLie(4,{[4,5],[4,6]})

o5 = {[6, 6, 6, 4], [6, 4, 6, 4], [5, 5, 5, 4], [5, 4, 5, 4], [4, 4, 6, 4],
     ------------------------------------------------------------------------
     [4, 4, 5, 4]}

o5 : List
i6 : i1=idealBasisLie(4,{[2,3],[4,6]})

o6 = {[6, 6, 6, 4], [6, 4, 6, 4], [4, 4, 6, 4], [3, 3, 3, 2], [3, 2, 3, 2],
     ------------------------------------------------------------------------
     [2, 2, 3, 2]}

o6 : List
i7 : i2=idealBasisLie(4,{[2,3],[4,5]})

o7 = {[5, 5, 5, 4], [5, 4, 5, 4], [4, 4, 5, 4], [3, 3, 3, 2], [3, 2, 3, 2],
     ------------------------------------------------------------------------
     [2, 2, 3, 2]}

o7 : List

The intersection of these ideals is decompidealLie.

i8 : intersectionLie(4,{i0,i1,i2})

o8 = {}

o8 : List

Here is the "quadrangel" arrangement, i.e., the graphical arrangement of the complete graph on four vertices. Its holonomy Lie algebra is not decomposable.

i9 : L = holonomyLie({{1,2,3},{1,4,5},{2,4,6},{3,5,6}})

o9 = L

o9 : LieAlgebra
i10 : decompidealLie 3

o10 = {[6, 5, 4], [5, 6, 4]}

o10 : List

Here is a way to obtain decompidealLie (which is not used in its program). The direct sum of the local Lie algebras may be obtained as follows

i11 : M=holonomyLie({{1,2,3},{a1,4,5},{a2,a4,6},{a3,a5,a6}})

o11 = M

o11 : LieAlgebra

and the map from L to M is given as

i12 : f=mapLie(M,L,{{{1,1},{[1],[a1]}},{{1,1},{[2],[a2]}},{{1,1},{[3],[a3]}},
              {{1,1},{[4],[a4]}},{{1,1},{[5],[a5]}},{{1,1},{[6],[a6]}}})

o12 = f

o12 : MapLie

and hence the ideal may be obtained as the kernel of f

i13 : kernelBasisLie(3,f)

o13 = {[6, 5, 4], [5, 6, 4]}

o13 : List

The symmetric group S4 operates on the vertices of K4 and this induces an action of S4 on the six edges, which in turn induces an action of S4 on L as automorphisms. One such permutation of the edges is (123)(465) but not (123)(456). It is possible to check, using symmCyclePermLie, if a permutation of the generators, written as a product of cycles, defines an automorphism of the Lie algebra.

i14 : 
      useLie L

o14 = L

o14 : LieAlgebra
i15 : symmCyclePermLie({{1,2,3},{4,5,6}})
the map is not welldefined
i16 : symmCyclePermLie({{1,2,3},{4,6,5}})

o16 = MapLie{...8...}

o16 : MapLie
i17 : peek oo

o17 = MapLie{1 => [2]      }
             2 => [3]
             3 => [1]
             4 => [6]
             5 => [4]
             6 => [5]
             sourceLie => L
             targetLie => L

The ideal decompidealLie is invariant under all automorphisms of L. Wee may use characterLie and a character table for S4 to determine its irreducible representation constituents. There are four conjugacy classes (except id). Representatives for them as permutation of the six generators are (23)(45), (123)(465), (16)(2354) and (16)(25) corresponding to one 2-cycle, one 3-cycle, one 4-cycle and a product of two 2-cycles.

i18 : dec4=decompidealLie 4

o18 = {[6, 6, 5, 4], [6, 5, 6, 4], [6, 5, 5, 4], [6, 4, 5, 4], [5, 6, 6, 4],
      -----------------------------------------------------------------------
      [5, 6, 5, 4], [5, 5, 6, 4], [5, 4, 6, 4], [4, 6, 5, 4]}

o18 : List
i19 : characterLie(4,{{2,3},{4,5}},dec4)

o19 = -1

o19 : QQ
i20 : characterLie(4,{{1,2,3},{4,6,5}},dec4)

o20 = 0

o20 : QQ
i21 : characterLie(4,{{1,6},{2,3,5,4}},dec4)

o21 = -1

o21 : QQ
i22 : characterLie(4,{{1,6},{2,5}},dec4)

o22 = 1

o22 : QQ

Making calculations with the character table, we see that decompidealLie 4 is the sum of the irreducible representations except the trivial representation.

See also